1000 '*************************************************************************
1010 '　　　　英熟語プログラム
1020 '                                            '92 Apr.4-12
1030 '                                                          by H.Miyamoto
1040 'SAVE "JUKUGO.BAS",A
1050 '*************************************************************************
1060 '=========メイン==========================================================
1070 '~~~~~~~~ ｼｮｷｾｯﾃｲ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1080 CLEAR:TJ$="熟語"
1090 GOSUB *CLSALL:CONSOLE 20,5,0,1
1100 COLOR 6:LOCATE 0,0:PRINT"英熟語のテストをはじめます！"
1110 COLOR 5:LOCATE 0,1:PRINT"テストの初期設定は以下のとおりです。"
1120 COLOR 7:LOCATE 2,2:PRINT"読み込んだ熟語を表示       → しない"
1130 COLOR 7:LOCATE 2,3:PRINT"表示する言語（英語,日本語）→ 両方"
1140 COLOR 7:LOCATE 2,4:PRINT"正解した熟語の色           → 変える"
1150 COLOR 7:LOCATE 2,5:PRINT"制限時間の設定             → しない"
1160 COLOR 7:LOCATE 2,6:PRINT"画面(stage)変更時の確認    → しない"
1170 COLOR 5:LOCATE 0,7:INPUT"設定しなおす場合は 1、必要がなければ、0 を入力してください。";YN$
1180 IF YN$<>"1" THEN H$="0":L$="2":RM$="1":TL$="0":GM$="0"
1190 DIM ENG$(99),JAP$(99),HYOJI$(99),KOTAE$(99),HYO$(99),KOT$(99),MH$(200),MK$(200)
1200 DIM KAISU(200),KAI(200)
1210 '~~~~~~~~ ﾗﾝｽｳ ﾊｯｾｲ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1220 GOSUB *JIKAN0
1230 TT=(H0-M0)*S0
1240 RANDOMIZE TT
1250 '~~~~~~~~ ERROR TRAP ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1260 ON ERROR GOTO *ERTP
1270 '~~~~~~~~ ﾌｧｲﾙ ﾖﾐｺﾐ･ﾍﾝｽｳ ｾｯﾃｲ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1280 MODE$="JUKUGO"
1290 CLS:LOCATE ,7:PRINT SPACE$(80)
1300 LOCATE ,19:COLOR 5:PRINT "何番目のテストをやりますか？"
1310 COLOR 7:PRINT "(  1〜 100:   ／ 101〜 200:   ／ 201〜 300:   ／ 301〜 400:   ／ 401〜 500:"
1320 PRINT " 501〜 600:   ／ 601〜 700:   ／ 701〜 800:   ／ 801〜 900:   ／ 901〜1000:   )"
1330 FOR I= 0 TO 1
1340  FOR J=0 TO 4
1350   LOCATE 16*J+11,20+I:COLOR 5:PRINT MID$(STR$(I*5+J),2,2)
1360  NEXT J
1370 NEXT I
1380 LOCATE 75,24:INPUT NO2$
1390 IF NO2$="" GOTO 1290
1400 NO2=INT(VAL(NO2$))
1410 IF NO2<0 OR NO2>9 THEN GOTO 1290
1420 NO2$=MID$(STR$(NO2),2,2)
1430 '~~~~~~~~ ﾀﾝｺﾞ･ｼﾞｭｸｺﾞ ﾉ ﾋｮｳｼﾞ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1440 GOSUB *CLSALL
1450 GOSUB *YOMIKOMI:GOSUB *CLSALL
1460 IF H$="0" OR H$="1" GOTO 1540
1470 LOCATE ,21:COLOR 5:PRINT "読み込んだ"+TJ$+"を表示しますか。"
1480 INPUT"( 表示する→1 ／表示しない→0 )";H$
1490 IF H$="" THEN H$="0"
1500 IF H$<>"0" AND H$<>"1" GOTO 1470
1510 IF H$="1" THEN GOSUB *HYOJI
1520 '~~~~~~~~ ｹﾞﾝｺﾞﾋｮｳｼﾞｾﾝﾀｸ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1530 GOSUB *CLSALL
1540 IF L$="0" OR L$="1" OR L$="2" GOTO 1570
1550 LOCATE ,21:COLOR 5:INPUT "英語を表示しますか、日本語を表示しますか。( 英語→0 ／日本語→1 ／両方→2 )";L$
1560 IF L$<>"0" AND L$<>"1" AND L$<>"2" GOTO 1550
1570 GOSUB *STIR
1580 '~~~~~~~~ ﾋｮｳｼﾞｼｮｸ ﾍﾝｺｳ ｾﾝﾀｸ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1590 CLS:IF RM$="0" OR RM$="1" GOTO 1720
1600 LOCATE ,21:COLOR 5:PRINT "正解した"+TJ$+"の色を変えますか、変えませんか。"
1610 INPUT"( 変えます→1 ／変えません→0 )";RM$
1620 IF RM$="" THEN RM$="0"
1630 IF RM$<>"0" AND RM$<>"1" GOTO 1600
1640 '~~~~~~~~ stage ﾍﾝｺｳｼﾞﾉ ｶｸﾆﾝ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1650 CLS:IF GM$="0" OR GM$="1" GOTO 1720
1660 LOCATE ,21:COLOR 5:PRINT "１０問終了後の stage 更新時に確認をしますか。"
1670 INPUT"( 確認します→1 ／確認しません→0 )";GM$
1680 IF GM$="" THEN GM$="0"
1690 IF GM$<>"0" AND GM$<>"1" GOTO 1600
1700 '~~~~~~~~ ｼﾞｶﾝｾｯﾃｲ ﾉ ｾﾝﾀｸ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1710 CLS
1720 COLOR 3:LOCATE ,21:PRINT "英"+TJ$+"テストをはじめます。"
1730 COLOR 6:LOCATE 26,21:PRINT "テスト中の入力キーは数字キーだけで行えます。"
1740 COLOR 4:PRINT "途中でやめる場合は [＊] キーを押して下さい。"
1750 IF TL$<>"" THEN COLOR 5:INPUT "確認できたら [RET] キーを押してください。";NUL$:TL=VAL(TL$):GOTO 1780
1760 COLOR 5:PRINT "目標時間を設定しますか。設定したい場合は時間（分）を入力して下さい。"
1770 INPUT "設定しない場合は、[RET] キーを押してください。";TL
1780 COLOR 7:CLS
1790 GOSUB *LIMIT
1800 '~~~~~~~~ ｼﾂﾓﾝ ﾋｮｳｼﾞ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1810 JU$="0123456789"
1820 FOR I=0 TO 9
1830  EJ=0
1840  GOSUB *SENTAKUJ
1850  GOSUB *QUEST
1860  IF L$="2" THEN GOSUB *EXCH:EJ=1:GOSUB *QUEST
1870 NEXT I
1880 GOSUB *OWARI2
1890 '=========サブルーチン====================================================
1900 '~~~~~~~~ ﾀﾝｺﾞ･ｼﾞｭｸｺﾞ ﾉ ﾅﾗﾍﾞｶｴ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1910 *STIR
1920 COLOR 6:PRINT "ただ今"+TJ$+"を並べ替えています。ちょと待っててね！"
1930 COLOR 7
1940 FOR I=0 TO 9
1950  IC$="0123456789"
1960  FOR J=0 TO 9
1970   NO=I*10+J
1980   LOCATE 73,0:PRINT NO2*100+NO+1
1990   GOSUB *SENTAKUI
2000   NO=I*10+NOI
2010   IF L$="1" THEN GOSUB *NIHONGO ELSE GOSUB *EIGO
2020  NEXT J
2030 NEXT I
2040 RETURN
2050 '~~~~~~~~ ﾋｮｳｼﾞ ﾄ ｼﾂﾓﾝ ﾉ ｹﾞﾝｺﾞｾｯﾃｲ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2060 *EIGO
2070 K=I*10+J
2080 HYOJI$(K)=ENG$(NO)
2090 KOTAE$(K)=JAP$(NO)
2100 RETURN
2110 *NIHONGO
2120 K=I*10+J
2130 HYOJI$(K)=JAP$(NO)
2140 KOTAE$(K)=ENG$(NO)
2150 RETURN
2160 *EXCH
2170 N=NOJ*10
2180 IC$="0123456789"
2190 FOR J=0 TO 9
2200  GOSUB *SENTAKUI
2210  HYO$(N+NOI)=HYOJI$(N+J):KOT$(N+NOI)=KOTAE$(N+J)
2220 NEXT J
2230 FOR J=0 TO 9
2240  HYOJI$(N+J)=KOT$(N+J):KOTAE$(N+J)=HYO$(N+J)
2250 NEXT J
2260 RETURN
2270 '~~~~~~~~ ﾌｧｲﾙ ﾖﾐｺﾐ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2280 *YOMIKOMI
2290 GOSUB *CLSALL
2300 COLOR 6:PRINT "ただ今ファイルを読み込み中です。ちょっと待っててね！"
2310 OPEN MODE$+NO2$+".DAT"FOR INPUT AS #1
2320 FOR I=0 TO 9
2330  FOR J=0 TO 9
2340   NO=I*10+J
2350   LOCATE 73,0:PRINT NO2*100+NO+1
2360   INPUT #1,EN$,JA$
2370   ENG$(NO)=EN$
2380   JAP$(NO)=JA$
2390  NEXT J
2400 NEXT I
2410 CLOSE #1
2420 RETURN
2430 '~~~~~~~~ ﾀﾝｺﾞ･ｼﾞｭｸｺﾞﾋｮｳｼﾞ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2440 *HYOJI
2450 FOR I=0 TO 4
2460  GOSUB *CLSALL
2470  COLOR 7
2480  FOR J=0 TO 19
2490   NO=I*20+J
2500   LOCATE ,J:PRINT"(";NO2*100+NO+1")";ENG$(NO);SPC(2);JAP$(NO)
2510  NEXT J
2520  COLOR 6:LOCATE ,21:PRINT NO2*100+I*20+1;"番目から";NO2*100+I*20+20;"番目までの";TJ$;"を表示しています。"
2530  COLOR 5:LOCATE ,22:INPUT"確認できたら [RET] キーを押してください。";NUL$
2540 NEXT I
2550 RETURN
2560 '~~~~~~~~ ｼﾂﾓﾝ ﾋｮｳｼﾞ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2570 *QUEST
2580  GOSUB *CLSALL
2590  COLOR 4:LOCATE 70,0:PRINT DATE$
2600  LOCATE 65,15:PRINT"FILE  :";NO2
2610  LOCATE 65,16:PRINT"stage :";I+1
2620  IF L$="2" THEN LOCATE 75,16:PRINT"-";EJ+1
2630  LOCATE 65,18:COLOR 3:PRINT"正解数: 0"
2640  COLOR 7
2650  IC$="0123456789"
2660  FOR K=0 TO 9
2670   GOSUB *SENTAKUI
2680   LOCATE ,NOI:PRINT "(";NOI;") ";HYOJI$(NOJ*10+NOI)
2690  NEXT K
2700  IC$="0123456789"
2710  FOR L=0 TO 9
2720   GOSUB *SENTAKUI
2730   LOCATE ,24:COLOR 5:PRINT "『"+KOTAE$(NOJ*10+NOI)+"』は何番目ですか？"
2740   Y=CSRLIN:Z$=""
2750   Z$=INKEY$
2760   COLOR 4:LOCATE 70,1:PRINT TIME$:LOCATE ,Y+1
2770   IF Z$="" GOTO 2740
2780   IF Z$="*" THEN GOSUB *CHUDAN:GOTO 2740
2790   IF ASC(Z$)<&H30 OR ASC(Z$)>&H39 THEN GOSUB *MISINP:GOTO 2740
2800   IF VAL(Z$)=NOI THEN GOSUB *MARU ELSE GOSUB *PEKE:GOTO 2730
2810   LOCATE 72,18:COLOR 3:IF L$="2" THEN PRINT KAZ-I*20-EJ*10 ELSE PRINT KAZ-I*10
2820  NEXT L
2830  IF GM$="1" THEN LOCATE ,20:COLOR 6:INPUT "次に進みますか。( 進みます→[RET] ／止めます→[＊] )";NUL$
2840 RETURN
2850 '~~~~~~~~ ｶﾞﾒﾝ ｼｮｳｷｮ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2860 *CLSALL
2870 CLS
2880 FOR N=0 TO 20
2890  LOCATE ,N:PRINT SPACE$(80)
2900 NEXT N
2910 RETURN
2920 *CLSM
2930 FOR N=2 TO 16
2940  LOCATE ,N:PRINT SPACE$(80)
2950 NEXT N
2960 RETURN
2970 '~~~~~~~~ ｽｳﾁ ｾﾝﾀｸ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2980 *SENTAKUJ
2990 IF LEN(JU$)=0 THEN RETURN
3000 R=INT(RND*LEN(JU$))+1
3010 NOJ=VAL(MID$(JU$,R,1))
3020 JU$=LEFT$(JU$,R-1)+RIGHT$(JU$,LEN(JU$)-R)
3030 RETURN
3040 *SENTAKUI
3050 IF LEN(IC$)=0 THEN RETURN
3060 R=INT(RND*LEN(IC$))+1
3070 NOI=VAL(MID$(IC$,R,1))
3080 IC$=LEFT$(IC$,R-1)+RIGHT$(IC$,LEN(IC$)-R)
3090 RETURN
3100 '~~~~~~~~ ﾆｭｳﾘｮｸｷｰ ﾁｪｯｸ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3110 *MISINP
3120 Y=CSRLIN
3130 COLOR 2:LOCATE 15,19:PRINT "入力キーが違います！"
3140 BEEP:FOR IM=1 TO 3000:NEXT IM
3150 COLOR 7:LOCATE 15,19:PRINT SPACE$(65)
3160 LOCATE ,Y
3170 RETURN
3180 '~~~~~~~~ ○×ﾊﾝﾃｲ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3190 *MARU
3200 COLOR 6:LOCATE 20:PRINT Z$:Y=CSRLIN
3210 COLOR 2:LOCATE 22,Y-1:PRINT "○":COLOR 7:PRINT
3220 LOCATE ,NOI
3230 IF RM$="1" THEN COLOR 1:PRINT "(";NOI;") ";HYOJI$(NOJ*10+NOI)
3240 LOCATE ,24
3250 KAZ=KAZ+1:FLAG=0
3260 RETURN
3270 *PEKE
3280 COLOR 6:LOCATE 20:PRINT Z$:Y=CSRLIN
3290 COLOR 2:LOCATE 22,Y-1:PRINT "×":COLOR 7:PRINT
3300 MIS=MIS+1:MNO=NOJ*10+NOI
3310 IF FLAG=0 THEN SMIS=SMIS+1:MH$(SMIS)=HYOJI$(MNO):MK$(SMIS)=KOTAE$(MNO):KAISU(MIS)=1:KAI(SMIS)=1:FLAG=1:GOTO 3330
3320 KAISU(MIS)=KAISU(MIS-1)+1:KAI(SMIS)=KAISU(MIS)
3330 RETURN
3340 '~~~~~~~~ ｼﾞｶﾝ ｾｯﾃｲ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3350 *JIKAN0
3360 T0$=TIME$
3370 H0=VAL(LEFT$(T0$,2))
3380 M0=VAL(MID$(T0$,4,2))
3390 S0=VAL(RIGHT$(T0$,2))
3400 T0=H0*3600+M0*60+S0
3410 RETURN
3420 *JIKAN1
3430 T1$=TIME$
3440 H1=VAL(LEFT$(T1$,2))
3450 M1=VAL(MID$(T1$,4,2))
3460 S1=VAL(RIGHT$(T1$,2))
3470 T1=H1*3600+M1*60+S1
3480 SEC=T1-T0
3490 MIN=SEC\60
3500 SEC=SEC-MIN*60
3510 RETURN
3520 '~~~~~~~~ ｼﾞｶﾝ ｾｲｹﾞﾝ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3530 *LIMIT
3540 LIM$="1"
3550 GOSUB *JIKAN0
3560 IF TL=<0 THEN RETURN ELSE TIME$ ON
3570 TL=T0+TL*60
3580 HL=INT(TL/3600)
3590 ML=(TL-HL*3600)\60
3600 SL=TL-HL*3600-ML*60
3610 IF TL=<0 THEN RETURN ELSE TIME$ ON
3620 DEF FNST$(X)=RIGHT$("0"+RIGHT$(STR$(X),LEN(STR$(X))-1),2)
3630 ON TIME$=FNST$(HL)+":"+FNST$(ML)+":"+FNST$(SL) GOSUB *ENCHO
3640 RETURN
3650 '~~~~~~~~ "*" ｷｰ ﾆﾖﾙ ﾁｭｳﾀﾞﾝ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3660 *CHUDAN
3670 IF TL>0 THEN TIME$ OFF
3680 Y=CSRLIN
3690 COLOR 6:LOCATE ,19:PRINT"終わりにしますか？ ( 終わります→1 ／終わりません→0 )"
3700 A$=""
3710 A$=INKEY$
3720 IF A$="" GOTO 3700
3730 LOCATE ,19:PRINT SPACE$(80)
3740 IF A$="1" THEN GOSUB *OWARI2 ELSE LOCATE ,Y+1
3750 IF TL>0 THEN TIME$ ON
3760 RETURN
3770 '~~~~~~~~ 3ﾌﾟﾝ ｴﾝﾁｮｳ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3780 *ENCHO
3790 TIME$ OFF:HELP OFF
3800 Y=CSRLIN
3810 COLOR 6:LOCATE ,19:INPUT"予定時間を過ぎました。まだ続けますか。( 続けます→1 ／やめます→0 )";A$
3820 LOCATE ,19:PRINT SPACE$(80)
3830 IF A$<>"1" AND A$<>"0" AND A$<>"" THEN GOTO 3810
3840 IF A$="1" THEN COLOR 2:PRINT"あと、３分間延長します。":TL=3:GOSUB *LIMIT:COLOR 7:LOCATE ,Y:HELP ON:RETURN
3850 GOSUB *OWARI2
3860 '~~~~~~~~ ﾏﾁｶﾞｲ ﾋｮｳｼﾞ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3870 *MISS
3880 IF MIS=0 THEN GOSUB *MANTEN:RETURN
3890 COLOR 6:LOCATE 0,0:PRINT USING "### 個の間違いがあります。";SMIS-SRM
3900 LOCATE 0,1:COLOR 6:PRINT"間違えた回数と"+TJ$+"は":COLOR 7
3910 J=(SMIS-1)\14
3920 FOR K=0 TO J
3930  GOSUB *CLSM
3940  IF SMIS-K*14-SRM>15 THEN M=14 ELSE M=SMIS-K*14-SRM
3950  FOR I=1 TO M
3960   LOCATE 0,I+1:PRINT USING "## 回";KAI(SRM+I+K*14):LOCATE 7,I+1:PRINT MH$(SRM+I+K*14);" → ";MK$(SRM+I+K*14)
3970  NEXT I
3980  IF J-K>0 THEN LOCATE ,16:COLOR 6:INPUT "確認できたら、[RET]キーを押してください。次の間違いを表示します。";NUL$:COLOR 7
3990 NEXT K
4000 CLS:COLOR 5:LOCATE ,20:PRINT "間違いをプリントアウトしますか。"
4010 PRINT "プリントする場合はプリンターを確認して１を入力してください。"
4020 INPUT "（必要がなければ、[RET]キーで終了できます）";PL$
4030 IF PL$<>"1" THEN RETURN
4040 LPRINT "テスト日："+DATE$
4050 LPRINT "ファイル名："+TJ$+"No."+NO2$
4060 LPRINT USING "かかった時間は###分 ## 秒 ";MIN,SEC
4070 LPRINT USING "得点は ### 点中 ### 点 です。";KAZ,KAZ-MIS
4080 IF KAZ>0 THEN LPRINT USING "正解率：### ％";PER%
4090 LPRINT
4100 LPRINT"間違えた回数と"TJ$+"は"
4110 FOR I=1 TO SMIS
4120  LPRINT USING "## 回"+SPACE$(2)+MH$(I)+" → "+MK$(I);KAI(I)
4130 NEXT
4140 RETURN
4150 '~~~~~~~~ ERROR TRAP ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
4160 *ERTP
4170 GOSUB *CLSALL
4180 COLOR 6:LOCATE ,20:PRINT"最初からやり直します。"
4190 COLOR 2:LOCATE ,21:INPUT"もっと真面目に入力してください！";NUL$
4200 RUN "JUKUGO"
4210 '~~~~~~~~ ﾄｸﾃﾝ･ｼﾞｶﾝ ｼｭｳｹｲ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
4220 *TOKUTEN
4230 IF KAZ>0 AND FLAG=0 THEN PER%=(1-SMIS/KAZ)*100
4240 IF KAZ>0 AND FLAG=1 THEN PER%=(1-SMIS/(KAZ+1))*100
4250 LOCATE ,17:COLOR 4:PRINT USING "かかった時間は###分 ## 秒 です。";MIN,SEC
4260 COLOR 6:PRINT USING "得点は ### 点中 ### 点 デシタ！";KAZ,KAZ-MIS
4270 IF KAZ>0 THEN LOCATE 32,CSRLIN-1:COLOR 5:PRINT USING "正解率：### ％";PER%
4280 RETURN
4290 '~~~~~~~~ ﾏﾝﾃﾝ ｼｮﾘ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
4300 *MANTEN
4310 LOCATE 0,2:COLOR 6:PRINT SPC(2);STR$(KAZ)+" 問中、間違いはありません！"
4320 IF KAZ>80 AND KAZ<100 THEN LOCATE ,3:PRINT"大変よくできました。"
4330 IF KAZ>=100 THEN LOCATE ,3:PRINT"パーフェクトです。君はえらい！"
4340 RETURN
4350 '~~~~~~~~ ｼｭｳﾘｮｳ ｶｸﾆﾝ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
4360 *OWARI1
4370 CLS:LOCATE ,22:COLOR 5:PRINT"もう一度やりますか。MENU に戻りますか。"
4380 INPUT"( やります→1 ／MENU に戻ります→0 )";A$
4390 RETURN
4400 '~~~~~~~~ ｼｭｳﾘｮｳ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
4410 *OWARI2
4420 IF LIM$<>"1" THEN GOSUB *CLSALL:GOTO 4480
4430 TIME$ OFF:HELP OFF:ON ERROR GOTO 0
4440 GOSUB *JIKAN1
4450 GOSUB *CLSALL
4460 GOSUB *TOKUTEN
4470 GOSUB *MISS
4480 GOSUB *OWARI1
4490 IF A$="1" GOTO 1080
4500 IF A$="0" OR A$= "" THEN COMMON TJ$:CHAIN "MENU"
4510 GOTO 4480