1000 '*************************************************************************
1010 '　　　　英単語プログラム
1020 '                                               '92 Apr.4-12
1030 '                                                          by H.Miyamoto
1040 'SAVE "TANGO.BAS",A
1050 '*************************************************************************
1060 '=========メイン==========================================================
1070 '~~~~~~~~ ｼｮｷｾｯﾃｲ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1080 CLEAR:TJ$="単語"
1090 GOSUB *CLSALL:CONSOLE 20,5,0,1
1100 COLOR 6:LOCATE 0,0:PRINT"英単語のテストをはじめます！"
1110 COLOR 5:LOCATE 0,1:PRINT"テストの初期設定は以下のとおりです。"
1120 COLOR 7:LOCATE 2,2:PRINT"読み込んだ単語を表示       → しない"
1130 COLOR 7:LOCATE 2,3:PRINT"表示する言語（英語,日本語）→ 両方"
1140 COLOR 7:LOCATE 2,4:PRINT"正解した単語の色           → 変える"
1150 COLOR 7:LOCATE 2,5:PRINT"制限時間の設定             → しない"
1160 COLOR 7:LOCATE 2,6:PRINT"画面(stage)変更時の確認    → しない"
1170 COLOR 5:LOCATE 0,7:INPUT"設定しなおす場合は 1、必要がなければ、0 を入力してください。";YN$
1180 IF YN$<>"1" THEN H$="0":L$="2":RM$="1":TL$="0":GM$="0"
1190 DIM ENG$(99),JAP$(99),HYOJI$(99),KOTAE$(99),HYO$(99),KOT$(99),MH$(200),MK$(200)
1200 DIM KAISU(200),KAI(200)
1210 '~~~~~~~~ ﾗﾝｽｳ ﾊｯｾｲ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1220 GOSUB *JIKAN0
1230 TT=(H0-M0)*S0
1240 RANDOMIZE TT
1250 '~~~~~~~~ ERROR TRAP ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1260 ON ERROR GOTO *ERTP
1270 '~~~~~~~~ ﾌｧｲﾙ ﾖﾐｺﾐ･ﾍﾝｽｳ ｾｯﾃｲ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1280 MODE$="TANGO"
1290 CLS:LOCATE ,7:PRINT SPACE$(80)
1300 LOCATE ,19:COLOR 5:PRINT "何番目のテストをやりますか？"
1310 COLOR 7:PRINT "(  1〜 100:   ／ 101〜 200:   ／ 201〜 300:   ／ 301〜 400:   ／ 401〜 500:"
1320 PRINT " 501〜 600:   ／ 601〜 700:   ／ 701〜 800:   ／ 801〜 900:   ／ 901〜1000:"
1330 PRINT "1001〜1100:   ／1101〜1200:   ／1201〜1300:   ／1301〜1400:   ／1401〜1500:"
1340 PRINT "1501〜1600:   ／1601〜1700:   ／1701〜1800:   ／1801〜1900:   ／1901〜2000:   )"
1350 FOR I= 0 TO 3
1360  FOR J=0 TO 4
1370   LOCATE 16*J+11,20+I:COLOR 5:PRINT MID$(STR$(I*5+J),2,2)
1380  NEXT J
1390 NEXT I
1400 COLOR 7:LOCATE 62,CSRLIN-1:PRINT" )               "
1410 LOCATE 75,24:INPUT NO2$
1420 IF NO2$="" GOTO 1290
1430 NO2=INT(VAL(NO2$))
1440 IF NO2<0 OR NO2>18 THEN GOTO 1290
1450 NO2$=MID$(STR$(NO2),2,2)
1460 '~~~~~~~~ ﾀﾝｺﾞ･ｼﾞｭｸｺﾞ ﾉ ﾋｮｳｼﾞ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1470 GOSUB *CLSALL
1480 GOSUB *YOMIKOMI:GOSUB *CLSALL
1490 IF H$="0" OR H$="1" GOTO 1570
1500 LOCATE ,21:COLOR 5:PRINT "読み込んだ"+TJ$+"を表示しますか。"
1510 INPUT"( 表示する→1 ／表示しない→0 )";H$
1520 IF H$="" THEN H$="0"
1530 IF H$<>"0" AND H$<>"1" GOTO 1500
1540 IF H$="1" THEN GOSUB *HYOJI
1550 '~~~~~~~~ ｹﾞﾝｺﾞﾋｮｳｼﾞｾﾝﾀｸ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1560 GOSUB *CLSALL
1570 IF L$="0" OR L$="1" OR L$="2" GOTO 1600
1580 LOCATE ,21:COLOR 5:INPUT "英語を表示しますか、日本語を表示しますか。( 英語→0 ／日本語→1 ／両方→2 )";L$
1590 IF L$<>"0" AND L$<>"1" AND L$<>"2" GOTO 1580
1600 GOSUB *STIR
1610 '~~~~~~~~ ﾋｮｳｼﾞｼｮｸ ﾍﾝｺｳ ｾﾝﾀｸ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1620 CLS:IF RM$="0" OR RM$="1" GOTO 1750
1630 LOCATE ,21:COLOR 5:PRINT "正解した"+TJ$+"の色を変えますか、変えませんか。"
1640 INPUT"( 変えます→1 ／変えません→0 )";RM$
1650 IF RM$="" THEN RM$="0"
1660 IF RM$<>"0" AND RM$<>"1" GOTO 1630
1670 '~~~~~~~~ stage ﾍﾝｺｳｼﾞﾉ ｶｸﾆﾝ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1680 CLS:IF GM$="0" OR GM$="1" GOTO 1750
1690 LOCATE ,21:COLOR 5:PRINT "１０問終了後の stage 更新時に確認をしますか。"
1700 INPUT"( 確認します→1 ／確認しません→0 )";GM$
1710 IF GM$="" THEN GM$="0"
1720 IF GM$<>"0" AND GM$<>"1" GOTO 1630
1730 '~~~~~~~~ ｼﾞｶﾝｾｯﾃｲ ﾉ ｾﾝﾀｸ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1740 CLS
1750 COLOR 3:LOCATE ,21:PRINT "英"+TJ$+"テストをはじめます。"
1760 COLOR 6:LOCATE 26,21:PRINT "テスト中の入力キーは数字キーだけで行えます。"
1770 COLOR 4:PRINT "途中でやめる場合は [＊] キーを押して下さい。"
1780 IF TL$<>"" THEN COLOR 5:INPUT "確認できたら [RET] キーを押してください。";NUL$:TL=VAL(TL$):GOTO 1810
1790 COLOR 5:PRINT "目標時間を設定しますか。設定したい場合は時間（分）を入力して下さい。"
1800 INPUT "設定しない場合は、[RET] キーを押してください。";TL
1810 COLOR 7:CLS
1820 GOSUB *LIMIT
1830 '~~~~~~~~ ｼﾂﾓﾝ ﾋｮｳｼﾞ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1840 JU$="0123456789"
1850 FOR I=0 TO 9
1860  EJ=0
1870  GOSUB *SENTAKUJ
1880  GOSUB *QUEST
1890  IF L$="2" THEN GOSUB *EXCH:EJ=1:GOSUB *QUEST
1900 NEXT I
1910 GOSUB *OWARI2
1920 '=========サブルーチン====================================================
1930 '~~~~~~~~ ﾀﾝｺﾞ･ｼﾞｭｸｺﾞ ﾉ ﾅﾗﾍﾞｶｴ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1940 *STIR
1950 COLOR 6:PRINT "ただ今"+TJ$+"を並べ替えています。ちょと待っててね！"
1960 COLOR 7
1970 FOR I=0 TO 9
1980  IC$="0123456789"
1990  FOR J=0 TO 9
2000   NO=I*10+J
2010   LOCATE 73,0:PRINT NO2*100+NO+1
2020   GOSUB *SENTAKUI
2030   NO=I*10+NOI
2040   IF L$="1" THEN GOSUB *NIHONGO ELSE GOSUB *EIGO
2050  NEXT J
2060 NEXT I
2070 RETURN
2080 '~~~~~~~~ ﾋｮｳｼﾞ ﾄ ｼﾂﾓﾝ ﾉ ｹﾞﾝｺﾞｾｯﾃｲ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2090 *EIGO
2100 K=I*10+J
2110 HYOJI$(K)=ENG$(NO)
2120 KOTAE$(K)=JAP$(NO)
2130 RETURN
2140 *NIHONGO
2150 K=I*10+J
2160 HYOJI$(K)=JAP$(NO)
2170 KOTAE$(K)=ENG$(NO)
2180 RETURN
2190 *EXCH
2200 N=NOJ*10
2210 IC$="0123456789"
2220 FOR J=0 TO 9
2230  GOSUB *SENTAKUI
2240  HYO$(N+NOI)=HYOJI$(N+J):KOT$(N+NOI)=KOTAE$(N+J)
2250 NEXT J
2260 FOR J=0 TO 9
2270  HYOJI$(N+J)=KOT$(N+J):KOTAE$(N+J)=HYO$(N+J)
2280 NEXT J
2290 RETURN
2300 '~~~~~~~~ ﾌｧｲﾙ ﾖﾐｺﾐ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2310 *YOMIKOMI
2320 GOSUB *CLSALL
2330 COLOR 6:PRINT "ただ今ファイルを読み込み中です。ちょっと待っててね！"
2340 OPEN MODE$+NO2$+".DAT"FOR INPUT AS #1
2350 FOR I=0 TO 9
2360  FOR J=0 TO 9
2370   NO=I*10+J
2380   LOCATE 73,0:PRINT NO2*100+NO+1
2390   INPUT #1,EN$,JA$
2400   ENG$(NO)=EN$
2410   JAP$(NO)=JA$
2420  NEXT J
2430 NEXT I
2440 CLOSE #1
2450 RETURN
2460 '~~~~~~~~ ﾀﾝｺﾞ･ｼﾞｭｸｺﾞﾋｮｳｼﾞ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2470 *HYOJI
2480 FOR I=0 TO 4
2490  GOSUB *CLSALL
2500  COLOR 7
2510  FOR J=0 TO 19
2520   NO=I*20+J
2530   LOCATE ,J:PRINT"(";NO2*100+NO+1")";ENG$(NO);SPC(2);JAP$(NO)
2540  NEXT J
2550  COLOR 6:LOCATE ,21:PRINT NO2*100+I*20+1;"番目から";NO2*100+I*20+20;"番目までの";TJ$;"を表示しています。"
2560  COLOR 5:LOCATE ,22:INPUT"確認できたら [RET] キーを押してください。";NUL$
2570 NEXT I
2580 RETURN
2590 '~~~~~~~~ ｼﾂﾓﾝ ﾋｮｳｼﾞ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2600 *QUEST
2610  GOSUB *CLSALL
2620  COLOR 4:LOCATE 70,0:PRINT DATE$
2630  LOCATE 65,15:PRINT"FILE  :";NO2
2640  LOCATE 65,16:PRINT"stage :";I+1
2650  IF L$="2" THEN LOCATE 75,16:PRINT"-";EJ+1
2660  LOCATE 65,18:COLOR 3:PRINT"正解数: 0"
2670  COLOR 7
2680  IC$="0123456789"
2690  FOR K=0 TO 9
2700   GOSUB *SENTAKUI
2710   LOCATE ,NOI:PRINT "(";NOI;") ";HYOJI$(NOJ*10+NOI)
2720  NEXT K
2730  IC$="0123456789"
2740  FOR L=0 TO 9
2750   GOSUB *SENTAKUI
2760   LOCATE ,24:COLOR 5:PRINT "『"+KOTAE$(NOJ*10+NOI)+"』は何番目ですか？"
2770   Y=CSRLIN:Z$=""
2780   Z$=INKEY$
2790   COLOR 4:LOCATE 70,1:PRINT TIME$:LOCATE ,Y+1
2800   IF Z$="" GOTO 2770
2810   IF Z$="*" THEN GOSUB *CHUDAN:GOTO 2770
2820   IF ASC(Z$)<&H30 OR ASC(Z$)>&H39 THEN GOSUB *MISINP:GOTO 2770
2830   IF VAL(Z$)=NOI THEN GOSUB *MARU ELSE GOSUB *PEKE:GOTO 2760
2840   LOCATE 72,18:COLOR 3:IF L$="2" THEN PRINT KAZ-I*20-EJ*10 ELSE PRINT KAZ-I*10
2850  NEXT L
2860  IF GM$="1" THEN LOCATE ,20:COLOR 6:INPUT "次に進みますか。( 進みます→[RET] ／止めます→[＊] )";NUL$
2870 RETURN
2880 '~~~~~~~~ ｶﾞﾒﾝ ｼｮｳｷｮ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
2890 *CLSALL
2900 CLS
2910 FOR N=0 TO 20
2920  LOCATE ,N:PRINT SPACE$(80)
2930 NEXT N
2940 RETURN
2950 *CLSM
2960 FOR N=2 TO 16
2970  LOCATE ,N:PRINT SPACE$(80)
2980 NEXT N
2990 RETURN
3000 '~~~~~~~~ ｽｳﾁ ｾﾝﾀｸ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3010 *SENTAKUJ
3020 IF LEN(JU$)=0 THEN RETURN
3030 R=INT(RND*LEN(JU$))+1
3040 NOJ=VAL(MID$(JU$,R,1))
3050 JU$=LEFT$(JU$,R-1)+RIGHT$(JU$,LEN(JU$)-R)
3060 RETURN
3070 *SENTAKUI
3080 IF LEN(IC$)=0 THEN RETURN
3090 R=INT(RND*LEN(IC$))+1
3100 NOI=VAL(MID$(IC$,R,1))
3110 IC$=LEFT$(IC$,R-1)+RIGHT$(IC$,LEN(IC$)-R)
3120 RETURN
3130 '~~~~~~~~ ﾆｭｳﾘｮｸｷｰ ﾁｪｯｸ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3140 *MISINP
3150 Y=CSRLIN
3160 COLOR 2:LOCATE 15,19:PRINT "入力キーが違います！"
3170 BEEP:FOR IM=1 TO 3000:NEXT IM
3180 COLOR 7:LOCATE 15,19:PRINT SPACE$(65)
3190 LOCATE ,Y
3200 RETURN
3210 '~~~~~~~~ ○×ﾊﾝﾃｲ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3220 *MARU
3230 COLOR 6:LOCATE 20:PRINT Z$:Y=CSRLIN
3240 COLOR 2:LOCATE 22,Y-1:PRINT "○":COLOR 7:PRINT
3250 LOCATE ,NOI
3260 IF RM$="1" THEN COLOR 1:PRINT "(";NOI;") ";HYOJI$(NOJ*10+NOI)
3270 LOCATE ,24
3280 KAZ=KAZ+1:FLAG=0
3290 RETURN
3300 *PEKE
3310 COLOR 6:LOCATE 20:PRINT Z$:Y=CSRLIN
3320 COLOR 2:LOCATE 22,Y-1:PRINT "×":COLOR 7:PRINT
3330 MIS=MIS+1:MNO=NOJ*10+NOI
3340 IF FLAG=0 THEN SMIS=SMIS+1:MH$(SMIS)=HYOJI$(MNO):MK$(SMIS)=KOTAE$(MNO):KAISU(MIS)=1:KAI(SMIS)=1:FLAG=1:GOTO 3360
3350 KAISU(MIS)=KAISU(MIS-1)+1:KAI(SMIS)=KAISU(MIS)
3360 RETURN
3370 '~~~~~~~~ ｼﾞｶﾝ ｾｯﾃｲ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3380 *JIKAN0
3390 T0$=TIME$
3400 H0=VAL(LEFT$(T0$,2))
3410 M0=VAL(MID$(T0$,4,2))
3420 S0=VAL(RIGHT$(T0$,2))
3430 T0=H0*3600+M0*60+S0
3440 RETURN
3450 *JIKAN1
3460 T1$=TIME$
3470 H1=VAL(LEFT$(T1$,2))
3480 M1=VAL(MID$(T1$,4,2))
3490 S1=VAL(RIGHT$(T1$,2))
3500 T1=H1*3600+M1*60+S1
3510 SEC=T1-T0
3520 MIN=SEC\60
3530 SEC=SEC-MIN*60
3540 RETURN
3550 '~~~~~~~~ ｼﾞｶﾝ ｾｲｹﾞﾝ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3560 *LIMIT
3570 LIM$="1"
3580 GOSUB *JIKAN0
3590 IF TL=<0 THEN RETURN ELSE TIME$ ON
3600 TL=T0+TL*60
3610 HL=INT(TL/3600)
3620 ML=(TL-HL*3600)\60
3630 SL=TL-HL*3600-ML*60
3640 IF TL=<0 THEN RETURN ELSE TIME$ ON
3650 DEF FNST$(X)=RIGHT$("0"+RIGHT$(STR$(X),LEN(STR$(X))-1),2)
3660 ON TIME$=FNST$(HL)+":"+FNST$(ML)+":"+FNST$(SL) GOSUB *ENCHO
3670 RETURN
3680 '~~~~~~~~ "*" ｷｰ ﾆﾖﾙ ﾁｭｳﾀﾞﾝ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3690 *CHUDAN
3700 IF TL>0 THEN TIME$ OFF
3710 COLOR 6:LOCATE ,19:PRINT"終わりにしますか？ ( 終わります→1 ／終わりません→0 )"
3720 Y=CSRLIN
3730 A$=""
3740 A$=INKEY$
3750 IF A$="" GOTO 3730
3760 LOCATE ,19:PRINT SPACE$(80)
3770 IF A$="1" THEN GOSUB *OWARI2 ELSE LOCATE ,Y+1
3780 IF TL>0 THEN TIME$ ON
3790 RETURN
3800 '~~~~~~~~ 3ﾌﾟﾝ ｴﾝﾁｮｳ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3810 *ENCHO
3820 TIME$ OFF
3830 Y=CSRLIN
3840 COLOR 6:LOCATE ,19:INPUT"予定時間を過ぎました。まだ続けますか。( 続けます→1 ／やめます→0 )";A$
3850 IF A$<>"1" AND A$<>"0" AND A$<>"" THEN GOTO 3840
3860 IF A$="1" THEN COLOR 2:PRINT"あと、３分間延長します。":TL=3:GOSUB *LIMIT:COLOR 7:LOCATE ,Y
3870 GOSUB *OWARI2
3880 '~~~~~~~~ ﾏﾁｶﾞｲ ﾋｮｳｼﾞ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
3890 *MISS
3900 IF MIS=0 THEN GOSUB *MANTEN:RETURN
3910 COLOR 6:LOCATE 0,0:PRINT USING "### 個の間違いがあります。";SMIS-SRM
3920 LOCATE 0,1:COLOR 6:PRINT"間違えた回数と"+TJ$+"は":COLOR 7
3930 J=(SMIS-1)\14
3940 FOR K=0 TO J
3950  GOSUB *CLSM
3960  IF SMIS-K*14-SRM>15 THEN M=14 ELSE M=SMIS-K*14-SRM
3970  FOR I=1 TO M
3980   LOCATE 0,I+1:PRINT USING "## 回";KAI(SRM+I+K*14):LOCATE 7,I+1:PRINT MH$(SRM+I+K*14);" → ";MK$(SRM+I+K*14)
3990  NEXT I
4000  IF J-K>0 THEN LOCATE ,16:COLOR 6:INPUT "確認できたら、[RET]キーを押してください。次の間違いを表示します。";NUL$:COLOR 7
4010 NEXT K
4020 CLS:COLOR 5:LOCATE ,20:PRINT "間違いをプリントアウトしますか。"
4030 PRINT "プリントする場合はプリンターを確認して１を入力してください。"
4040 INPUT "（必要がなければ、[RET]キーで終了できます）";PL$
4050 IF PL$<>"1" THEN RETURN
4060 LPRINT "テスト日："+DATE$
4070 LPRINT "ファイル名："+TJ$+"No."+NO2$
4080 LPRINT USING "かかった時間は###分 ## 秒 ";MIN,SEC
4090 LPRINT USING "得点は ### 点中 ### 点 です。";KAZ,KAZ-MIS
4100 IF KAZ>0 THEN LPRINT USING "正解率：### ％";PER%
4110 LPRINT
4120 LPRINT"間違えた回数と"TJ$+"は"
4130 FOR I=1 TO SMIS
4140  LPRINT USING "## 回"+SPACE$(2)+MH$(I)+" → "+MK$(I);KAI(I)
4150 NEXT
4160 RETURN
4170 '~~~~~~~~ ERROR TRAP ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
4180 *ERTP
4190 GOSUB *CLSALL
4200 COLOR 6:LOCATE ,20:PRINT"最初からやり直します。"
4210 COLOR 2:LOCATE ,21:INPUT"もっと真面目に入力してください！";NUL$
4220 RUN "TANGO"
4230 '~~~~~~~~ ﾄｸﾃﾝ･ｼﾞｶﾝ ｼｭｳｹｲ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
4240 *TOKUTEN
4250 IF KAZ>0 AND FLAG=0 THEN PER%=(1-SMIS/KAZ)*100
4260 IF KAZ>0 AND FLAG=1 THEN PER%=(1-SMIS/(KAZ+1))*100
4270 LOCATE ,17:COLOR 4:PRINT USING "かかった時間は###分 ## 秒 です。";MIN,SEC
4280 COLOR 6:PRINT USING "得点は ### 点中 ### 点 デシタ！";KAZ,KAZ-MIS
4290 IF KAZ>0 THEN LOCATE 32,CSRLIN-1:COLOR 5:PRINT USING "正解率：### ％";PER%
4300 RETURN
4310 '~~~~~~~~ ﾏﾝﾃﾝ ｼｮﾘ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
4320 *MANTEN
4330 LOCATE 0,2:COLOR 6:PRINT SPC(2);STR$(KAZ)+" 問中、間違いはありません！"
4340 IF KAZ>80 AND KAZ<100 THEN LOCATE ,3:PRINT"大変よくできました。"
4350 IF KAZ>=100 THEN LOCATE ,3:PRINT"パーフェクトです。君はえらい！"
4360 RETURN
4370 '~~~~~~~~ ｼｭｳﾘｮｳ ｶｸﾆﾝ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
4380 *OWARI1
4390 CLS:LOCATE ,22:COLOR 5:PRINT"もう一度やりますか。MENU に戻りますか。"
4400 INPUT"( やります→1 ／MENU に戻ります→0 )";A$
4410 RETURN
4420 '~~~~~~~~ ｼｭｳﾘｮｳ ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
4430 *OWARI2
4440 IF LIM$<>"1" THEN GOSUB *CLSALL:GOTO 4500
4450 TIME$ OFF:ON ERROR GOTO 0
4460 GOSUB *JIKAN1
4470 GOSUB *CLSALL
4480 GOSUB *TOKUTEN
4490 GOSUB *MISS
4500 GOSUB *OWARI1
4510 IF A$="1" GOTO 1080
4520 IF A$="0" OR A$="" THEN COMMON TJ$:CHAIN "MENU"
4530 GOTO 4500